Interfacing DG600F Coin Acceptor to Arduino

I helped a kid at the local STEM school with this project. Sparkfun has a good video on getting the coin acceptor programmed, and they have a link to the datasheet which is fairly readable, but I could find no sample code anywhere so I thought I would post what we did for others.

The DG600F Coin Acceptor is available at Sparkfun. It looks like this:

This is a pretty cool little device. It was easy to program in coins and interface to the arduino. The only downside I see is it doesn’t make change. But if you are buying time, that is just fine.

Their project is to use an arduino to determine the dollar amount of coins input into the coin acceptor, then for every $.01, let a user play games on a raspberry Pi for a minute. We decided to let the Arduino count the dollar amount, decide how much time that would buy, then simply raise a pin HIGH when there was time left. That pin would be connected to the RPI and the RPI programmer could read that pin to decide if there is time left to keep playing.

The hardware is connected like this:

We configured the coin acceptor to output serial (moved dip switch 3 to on). It defaults to 4800 baud so we stuck with that and just made sure the code used the same baud rate. We programmed the coin acceptor for .01, .05, .10, and $.25. We tried $.50, but it got caught in the mechanism and decided not to try again.

The following code is quite simple. It reads coin amounts from the coin acceptor and uses that to increase a timer. As long as the timer is > 0, it keeps pin 13 high (which has an LED connected on the board to provide feedback that there is still time).

I wanted to allow the student to be able to use Serial.print to debug the code, so we used the SoftwareSerial library to use pin 2 to receive serial data.

#include <Arduino.h>
#include <SoftwareSerial.h>

SoftwareSerial mySerial(2,3); // RX, TX

int secondsRemaining = 0;
void setup() {
    // Open serial communications and wait for port to open:
    Serial.begin(9600);
    Serial.println("Coin Acceptor Ready!");

    // set the data rate for the SoftwareSerial port
    mySerial.begin(4800);

    pinMode(13, OUTPUT);

    }

void loop() {
    int i;
    unsigned long lastMillis = millis();

    while (true) {
        // any input coming from coin acceptor?
        if (mySerial.available()) {
            // read input, which is a 1 byte integer
            i=mySerial.read();
            // ignore any 255 amounts
            if (i != 255) {
                // increment time based on coin amount
                secondsRemaining = secondsRemaining + i * 60;
                Serial.print("Time Left is ");
                Serial.print(secondsRemaining);
                Serial.println(" remaining");
                }
            }
        if ((millis() - lastMillis) > 1000UL) {
            // decrement the time remaining by 1 sec
            lastMillis = millis();
            if (secondsRemaining > 0) {
                secondsRemaining = secondsRemaining - 1;
                }
            if (secondsRemaining > 0)
                digitalWrite(13, HIGH);
            else
                digitalWrite(13, LOW);
            Serial.print("Time Left is ");
            Serial.print(secondsRemaining);
            Serial.println(" remaining");
            }
        } // while

    }